Оживляем дисплей от приборной панели автобуса

#include <SPI.h>
#include <mcp2515.h>

#define CAN_CS_PIN   3
#define CAN_INT_PIN  2

// Адреса источников (SA)
#define SA_ENGINE        17   // 0x11
#define SA_TRANSMISSION   3   // 0x03

MCP2515 mcp2515(CAN_CS_PIN);

unsigned long lastSend = 0;
const unsigned long sendInterval = 100;

// --- Параметры двигателя ---
uint16_t engineRpm      = 800;
uint8_t  coolantTemp    = 80;
int8_t   gear           = 125; //125 = N; < 125 = R; > 125 = F
uint16_t vehicleSpeed   = 0;
uint8_t  fuelLevel      = 75;
uint16_t oilPressure    = 400;

// --- Электрика ---
uint16_t batteryVoltage    = 480;   // 24.00 V (SPN 168)
int16_t  netBatteryCurrent = 0;     // А (SPN 114, 1 A/bit, знаковый)
uint16_t alternatorCurrent = 50;    // А (SPN 115, 1 A/bit)
uint16_t chargingVoltage   = 480;  // 24.00 V (SPN 167)

// --- Температуры ---
uint8_t  oilTemp          = 90;   // SPN 175, °C (+40 offset)
uint8_t  turboOilTemp     = 120;  // SPN 176, °C (+40 offset)
uint8_t  transmissionTemp = 70;   // SPN 177, °C (+40 offset)
uint8_t  fuelTemp         = 25;   // SPN 174, °C (+40 offset)
int16_t  ambientTempRaw   = 2931; // SPN 171, 0.03125 °C/bit, -273 offset

bool addressClaimedSent = false;

void setup() {
  mcp2515.reset();
  mcp2515.setBitrate(CAN_250KBPS, MCP_8MHZ);
  mcp2515.setNormalMode();
}

void loop() {
  if (!addressClaimedSent) {
    sendAddressClaimed(SA_ENGINE);
    sendAddressClaimed(SA_TRANSMISSION);
    addressClaimedSent = true;
    delay(50);
  }

  if (millis() - lastSend >= sendInterval) {
    lastSend = millis();

    // Имитация изменений
    engineRpm    = constrain(engineRpm + random(-20, 20), 600, 2500);
    coolantTemp  = constrain(coolantTemp + random(-1, 1), 70, 95);
    gear         = random(125, 134);
    vehicleSpeed = map(engineRpm, 600, 2500, 0, 80);
    fuelLevel    = constrain(fuelLevel + random(-1, 1), 0, 100);
    oilPressure  = constrain(oilPressure + random(-10, 10), 200, 600);

    batteryVoltage    = constrain(batteryVoltage + random(-5, 5), 420, 480);
    netBatteryCurrent = constrain(netBatteryCurrent + random(-2, 2), -30, 30);
    alternatorCurrent = constrain(alternatorCurrent + random(-2, 2), 30, 80);
    chargingVoltage   = constrain(chargingVoltage + random(-5, 5), 420, 480);

    oilTemp          = constrain(oilTemp + random(-1, 1), 80, 110);
    turboOilTemp     = constrain(turboOilTemp + random(-2, 2), 100, 150);
    transmissionTemp = constrain(transmissionTemp + random(-1, 1), 60, 95);
    fuelTemp         = constrain(fuelTemp + random(-1, 1), 15, 45);
    ambientTempRaw   = constrain(ambientTempRaw + random(-10, 10), 2800, 3100);

    // Отправка сообщений
    sendEEC1(engineRpm);
    sendET1(coolantTemp, oilTemp, turboOilTemp, fuelTemp);
    sendTC1(gear);
    sendCCVS(vehicleSpeed);
    sendFLI(fuelLevel);
    sendEOP(oilPressure);
    sendVEP1(batteryVoltage, netBatteryCurrent, alternatorCurrent, chargingVoltage);
    sendTRF1(transmissionTemp);
    sendAMB(ambientTempRaw);
  }
}

// ------------------------------------------------------------------
// Address Claimed (PGN 60928)
// ------------------------------------------------------------------
void sendAddressClaimed(uint8_t sourceAddress) {
  struct can_frame frame;
  frame.can_id = (6UL << 26) | (60928UL << 8) | sourceAddress;
  frame.can_id |= CAN_EFF_FLAG;
  frame.can_dlc = 8;

  frame.data[0] = 0x01;
  frame.data[1] = 0x00;
  frame.data[2] = 0xAB;
  frame.data[3] = 0x00;
  frame.data[4] = 0x00;
  frame.data[5] = 0x00;
  frame.data[6] = 0x00;
  frame.data[7] = 0x00;

  mcp2515.sendMessage(&frame);
}

// ------------------------------------------------------------------
// EEC1 (PGN 61444) — обороты двигателя (SPN 190), SA = 17
// ------------------------------------------------------------------
void sendEEC1(uint16_t rpm) {
  struct can_frame frame;
  frame.can_id = (6UL << 26) | (61444UL << 8) | SA_ENGINE;
  frame.can_id |= CAN_EFF_FLAG;
  frame.can_dlc = 8;

  uint16_t rpmRaw = rpm / 0.125;
  frame.data[3] = rpmRaw & 0xFF;
  frame.data[4] = (rpmRaw >> 8) & 0xFF;

  frame.data[0] = 0xFF;
  frame.data[1] = 0xFF;
  frame.data[2] = 0xFF;
  frame.data[5] = 0xFF;
  frame.data[6] = 0xFF;
  frame.data[7] = 0xFF;

  mcp2515.sendMessage(&frame);
}

// ------------------------------------------------------------------
// ET1 (PGN 65262) — температуры двигателя, SA = 17
// SPN 110: байт 1, SPN 174: байт 2, SPN 175: байты 3-4, SPN 176: байты 5-6
// ------------------------------------------------------------------
void sendET1(uint8_t coolant, uint8_t oil, uint8_t turboOil, uint8_t fuel) {
  struct can_frame frame;
  frame.can_id = (6UL << 26) | (65262UL << 8) | SA_ENGINE;
  frame.can_id |= CAN_EFF_FLAG;
  frame.can_dlc = 8;

  frame.data[0] = coolant + 40;           // SPN 110, байт 1 (ОЖ)
  frame.data[1] = fuel + 40;              // SPN 174, байт 2 (топливо)
  frame.data[2] = (oil + 40) & 0xFF;      // SPN 175, байт 3 (масло ДВС, младший)
  frame.data[3] = 0xFF;                   // SPN 175, байт 4 (старший, 0xFF = не используется)
  frame.data[4] = (turboOil + 40) & 0xFF; // SPN 176, байт 5 (масло турбины, младший)
  frame.data[5] = 0xFF;                   // SPN 176, байт 6 (старший)
  frame.data[6] = 0xFF;
  frame.data[7] = 0xFF;

  mcp2515.sendMessage(&frame);
}

// ------------------------------------------------------------------
// TC1 (PGN 61445) — выбранная передача (SPN 524), SA = 3
// ------------------------------------------------------------------
void sendTC1(int8_t gear) {
  struct can_frame frame;
  frame.can_id = (6UL << 26) | (61445UL << 8) | SA_TRANSMISSION;
  frame.can_id |= CAN_EFF_FLAG;
  frame.can_dlc = 8;

  if (gear == 0) {
    frame.data[0] = 0;
  } else if (gear > 0) {
    frame.data[0] = gear;
  } else {
    frame.data[0] = 256 + gear;
  }

  for (int i = 1; i < 8; i++) frame.data[i] = 0xFF;
  mcp2515.sendMessage(&frame);
}

// ------------------------------------------------------------------
// CCVS (PGN 65265) — скорость (SPN 84), SA = 17
// ------------------------------------------------------------------
void sendCCVS(uint16_t speed) {
  struct can_frame frame;
  frame.can_id = (6UL << 26) | (65265UL << 8) | SA_ENGINE;
  frame.can_id |= CAN_EFF_FLAG;
  frame.can_dlc = 8;

  uint16_t speedRaw = speed * 256;
  frame.data[1] = speedRaw & 0xFF;
  frame.data[2] = (speedRaw >> 8) & 0xFF;

  frame.data[0] = 0xFF;
  for (int i = 3; i < 8; i++) frame.data[i] = 0xFF;
  mcp2515.sendMessage(&frame);
}

// ------------------------------------------------------------------
// FLI (PGN 65276) — уровень топлива (SPN 96), SA = 17
// ------------------------------------------------------------------
void sendFLI(uint8_t fuelLevel) {
  struct can_frame frame;
  frame.can_id = (6UL << 26) | (65276UL << 8) | SA_ENGINE;
  frame.can_id |= CAN_EFF_FLAG;
  frame.can_dlc = 8;

  frame.data[1] = fuelLevel / 0.4;

  frame.data[0] = 0xFF;
  for (int i = 2; i < 8; i++) frame.data[i] = 0xFF;
  mcp2515.sendMessage(&frame);
}

// ------------------------------------------------------------------
// EOP (PGN 65263) — давление масла (SPN 100), SA = 17
// ------------------------------------------------------------------
void sendEOP(uint16_t pressure) {
  struct can_frame frame;
  frame.can_id = (6UL << 26) | (65263UL << 8) | SA_ENGINE;
  frame.can_id |= CAN_EFF_FLAG;
  frame.can_dlc = 8;

  frame.data[3] = pressure / 4; // разрешение 4 кПа/бит

  frame.data[0] = 0xFF;
  frame.data[1] = 0xFF;
  frame.data[2] = 0xFF;
  frame.data[4] = 0xFF;
  frame.data[5] = 0xFF;
  frame.data[6] = 0xFF;
  frame.data[7] = 0xFF;

  mcp2515.sendMessage(&frame);
}

// ------------------------------------------------------------------
// VEP1 (PGN 65271) — электрическая система, SA = 17
// SPN 114: байты 1-2, SPN 115: байты 3-4, SPN 167: байты 5-6, SPN 168: байты 7-8
// ------------------------------------------------------------------
void sendVEP1(uint16_t battVolt, int16_t netCurr, uint16_t altCurr, uint16_t chgVolt) {
  struct can_frame frame;
  frame.can_id = (6UL << 26) | (65271UL << 8) | SA_ENGINE;
  frame.can_id |= CAN_EFF_FLAG;
  frame.can_dlc = 8;

  // SPN 114: Net Battery Current, байты 1-2, 1 A/bit, знаковый
  frame.data[0] = netCurr & 0xFF;
  frame.data[1] = (netCurr >> 8) & 0xFF;

  // SPN 115: Alternator Current, байты 3-4, 1 A/bit
  frame.data[2] = altCurr & 0xFF;
  frame.data[3] = (altCurr >> 8) & 0xFF;

  // SPN 167: Charging System Potential, байты 5-6
  frame.data[4] = chgVolt & 0xFF;
  frame.data[5] = (chgVolt >> 8) & 0xFF;

  // SPN 168: Battery Potential / Power Input 1, байты 7-8
  frame.data[6] = battVolt & 0xFF;
  frame.data[7] = (battVolt >> 8) & 0xFF;

  mcp2515.sendMessage(&frame);
}

// ------------------------------------------------------------------
// TRF1 (PGN 65272) — температура масла в КПП (SPN 177), SA = 3
// SPN 177 находится в байте 2 (data[1]), 1 °C/bit, -40 смещение
// ------------------------------------------------------------------
void sendTRF1(uint8_t temp) {
  struct can_frame frame;
  frame.can_id = (6UL << 26) | (65272UL << 8) | SA_TRANSMISSION;
  frame.can_id |= CAN_EFF_FLAG;
  frame.can_dlc = 8;

  frame.data[0] = 0xFF;      // SPN 126 (oil pressure) — не используется
  frame.data[1] = temp + 40; // SPN 177, байт 2
  frame.data[2] = 0xFF;      // SPN 161 (oil level) — не используется
  frame.data[3] = 0xFF;
  frame.data[4] = 0xFF;
  frame.data[5] = 0xFF;
  frame.data[6] = 0xFF;
  frame.data[7] = 0xFF;

  mcp2515.sendMessage(&frame);
}

// ------------------------------------------------------------------
// AMB (PGN 65269) — температура окружающего воздуха (SPN 171), SA = 17
// SPN 171: байты 4-5, 0.03125 °C/bit, смещение -273 °C
// ------------------------------------------------------------------
void sendAMB(int16_t tempRaw) {
  struct can_frame frame;
  frame.can_id = (6UL << 26) | (65269UL << 8) | SA_ENGINE;
  frame.can_id |= CAN_EFF_FLAG;
  frame.can_dlc = 8;

  frame.data[0] = 0xFF;                   // SPN 108 — байт 1
  frame.data[1] = 0xFF;                   // SPN 108 — байт 2
  frame.data[2] = 0xFF;                   // SPN 170 — байт 3
  frame.data[3] = tempRaw & 0xFF;         // SPN 171, байт 4 (младший)
  frame.data[4] = (tempRaw >> 8) & 0xFF;  // SPN 171, байт 5 (старший)
  frame.data[5] = 0xFF;                   // SPN 172 — байт 6
  frame.data[6] = 0xFF;                   // SPN 173 — байт 7
  frame.data[7] = 0xFF;                   // SPN 79 — байт 8

  mcp2515.sendMessage(&frame);
}